BLOCK NUMBER 15

( Controlled Reference Words Set - Load Block )                 
( Copyright  [ c ]  1992 by BDS Software )                      
decimal                                                         
cr cr                                                           
.( Loading Controlled Reference Words Set ) cr cr               
.(     Loading Block 1 of 4 ) 16 load cr                        
.(     Loading Block 2 of 4 ) 17 load cr                        
.(     Loading Block 3 of 4 ) 18 load cr                        
.(     Loading Block 4 of 4 ) 19 load cr cr                     
.( Controlled Reference Words Set Loaded.        )              
                                                                
                                                                
                                                                
                                                                
                                                                
                                                                

BLOCK NUMBER 16

( Controlled Reference Words Set - 1/4 )                        
( Copyright [ c ] 1992 by BDS Software )                        
decimal 16 base !                                               
: --> ( -- ) 0 >in ! 1 blk +! ; immediate                       
: .r ( n +n -- ) >r dup abs 0 <# #s rot sign #> r> over - spaces
     type ;                                                     
: u.r ( u +n -- ) >r 0 <# #s #> r> over - spaces type ;         
create 2* ( w1 -- w2 ) here dup 2- ! 3406 , 3706 , 5849 , 3606 ,
     3506 , AEA1 , 6E91 ,                                       
: bl ( -- 32 ) 20 ;                                             
: blank ( addr u -- ) 20 fill ;                                 
: c, ( 16b -- ) 1 allot here 1- c! ;                            
: dump ( addr u -- ) 0 do cr dup 6 u.r space 8 0 do dup @ 6 u.r 
     2+ loop 10 +loop drop ;                                    
: empty-buffers ( -- ) 6370 execute ;                           
: end ( flag -- ) [compile] until ; immediate decimal           

BLOCK NUMBER 17

( Controlled Reference Words Set - 2/4 )                        
( Copyright [ c ] 1992 by BDS Software )                        
decimal 16 base !                                               
: erase ( addr u -- ) 0 fill ;                                  
: hex ( -- ) 10 base ! ;                                        
create xitokl ( -- flag ) here dup 2- ! 3416 , CC02 , DBFD ,    
     5B0C , FC01 , D1C3 , 01DA , 3606 , BD5B , 0E37 , 1037 ,    
     068C , 0000 , 2703 , CC01 , DA83 , 01DA , FD01 , D136 ,    
     1035 , 16AE , A16E , 9112 ,                                
create xitokc ( -- addr ) here dup 2- ! 3410 , AE9F , 098B ,    
     3610 , 3510 , AEA1 , 6E91 ,                                
create xisrch ( addr1 -- [ addr2 flag ] or [ flag] ) 0007 here  
     2- ! 59D7 , 000D ,                                         
create xizmbr ( -- [ wd flag ] or [ w flag ] or [ flag ] ) 0007 
     here 2- ! 5A69 , 000D ,                                    
decimal                                                         

BLOCK NUMBER 18

( Controlled Reference Words Set - 3/4 )                        
( Copyright [ c ] 1992 by BDS Software )                        
decimal 16 base !                                               
: interpi ( -- ) begin xitokl not while xitokc xisrch not if    
     execute else xizmbr 0= if here 1+ here c@ type ." ?" quit  
     then then repeat ;                                         
create interpl ( -- ) here dup 2- ! 3620 , 108E , 5BFC , AEA1 , 
     6E91 ,                                                     
: interpret ( -- ) blk @ if interpl else interpi then ;         
create k ( -- w ) here dup 2- ! 3406 , ECE8 , 0EE3 , E810 ,     
     3606 , 3506 , AEA1 , 6E91 ,                                
: scr ( -- addr ) 23 ;                                          
: list ( u -- ) dup scr ! block cr 400 type ;                   
: octal ( -- ) 8 base ! ;                                       
decimal                                                         
                                                                

BLOCK NUMBER 19

( Controlled Reference Words Set - 4/4 )                        
( Copyright [ c ] 1992 by BDS Software )                        
decimal 16 base !                                               
: query ( -- ) 0 blk ! 0 >in ! tib 100 expect 0 >in ! span @    
     #tib ! ;                                                   
create recurse ( -- ) here dup 2- ! 3416 , 9E1D , E600 , C47F , 
     3A30 , 05AF , 9F00 , 1BDC , 1BC3 , 0002 , DD1B , 3516 ,    
     AEA1 , 6E91 , immediate                                    
create sp@ ( -- addr ) here dup 2- ! 3410 , 1F31 , 3610 , 3510 ,
     AEA1 , 6E91 ,                                              
: thru ( u1 u2 -- ) 1+ swap do i load loop ;                    
decimal